/*-- Classic scenario section --*/

#strict 2

public func SectionName() { return "Classic"; }

public func SpawnpointLocations() { return [[550, 282], [603, 205], [682, 282], [784, 227], [912, 168], [1040, 120],
	[648, 460], [432, 438], [170, 118], [299, 170], [441, 230], [1175, 290], [105, 380], [910, 400], [560, 610]]; }

protected func Initialize()
{
	// Moving bricks
	var bricks = [CreateObject(BRK2, 225, 150, NO_OWNER), CreateObject(BRK2, 985, 150, NO_OWNER)];

	if (ambienceEnabled)
	{
		// Background Sound
		if (mode != MODE_Apocalyptic && mode != MODE_Festive) SoundLevel("Ambience", 70);
		
		// Fog
		for (var i; i < 300; ++i)
		{
			CreateParticle("Fog", Random(LandscapeWidth()), Random(LandscapeHeight()) + 500, RandomX(3, 9), 0, RandomX(1000, 1500));
		}
		
		// Rain
		if (mode != MODE_Festive) AddEffect("Rain", 0, 20, 1);
		
		// Create sun and lenseflare
		CreateObject(SONE, 0, 0, NO_OWNER);
		CreateObject(LENS, 0, 0, NO_OWNER);
	}
	
	if (mode == MODE_Apocalyptic)
	{
		// Rock fall
		for (var i = 0; i < 10; ++i)
		{
			CreateObject(RCKF, 0, 0, NO_OWNER);
		}
		
		// Fire rain
		AddEffect("FireRain", 0, 20, 1);
		CreateObject(FRRN, 0, 0, NO_OWNER);
		
		// Background sound
		SoundLevel("ExtremeAmbience", 100);
		
		// Modulate brick color (object + material)
		for (var brick in bricks)
		{
			brick->SetClrModulation(RGB(220, 20, 20));
		}
		
		SetMaterialColor(Material("Brick"), 100, 0, 0, 150, 0, 0, 20, 0, 0);
	}
	
	if (mode == MODE_Festive)
	{
		// Chilly ambience
		if (ambienceEnabled) SoundLevel("FestiveAmbience", 60);
		
		// Modulate brick color (object + material)
		for (var brick in bricks)
		{
			brick->SetClrModulation(RGB(189, 243, 255));
		}
		SetMaterialColor(Material("Brick"), 100, 100, 230, 150, 150, 255, 30, 30, 50);
	}
}